Snippets Project Page

Author: Dazuz

Added: 5y

Updated: 5y

mIRC: 7.62

Hits: 1,421

Downloads: 39

Review: entropy

Size: 32.91KB

 0  0

Login to vote.

Colour Picker
v1.1

A little @picwin Colour Picker tool.

Generates a fullish RGB and mIRC colour bitmaps out of thin air!

/CP opens the window, menubar has Colour Picker menu.

Screenshot...
Download
JSON
▲ Review
▲ Log
▼ Source
  1. /*
  2. Colour Picker for mIRC v7.62+
  3.  
  4. Version:  1.1
  5. Coded by: Dazuz @ QuakeNet
  6.  
  7.  
  8. 1.1 (2020-08-03)
  9. - Changed text box background colour from hilight to inverted text colour.
  10.  
  11. 1.0 (2020-08-02)
  12. - Initial release.
  13. */
  14.  
  15. ;This alias creates $scriptdirCube.ico file. Feel free to remove the alias, it won't break anything important.
  16. alias cp.createicon {
  17.   set -l %icon $qt($scriptdirCube.ico)
  18.   if (!$isfile(%icon)) {
  19.     bset -t & 1 Y2BgBEIBAQYgUGDIYGFgEAOyNIBYACzCAJQFkQwMDiwMGOD///+MtMBrt+9oRMak6steN+U/MiZkDrq+zMPL/6c/PPSfGHOw6YNhdP3I5sD0Y9NHSD8II+vHpnco63/x8+v/vS/uwjGx+kH6YBhZPzZzkPXPO7sHRS8u/SDce2wTin6YGejm4NKHrheXOaTow2UOqfpIxaASgBIMAA==
  20.     if ($decode(&,bm)) && ($decompress(&,bm1)) && ($sha1(&,1) == ae378536e1f7af22066cb722dd04739a5a7fe8a4) bwrite %icon 0 &
  21.   }
  22. }
  23.  
  24. on *:load: {
  25.   if ($version < 7.62) {
  26.     echo $color(info) -at * Unsupported mIRC version, please update to $v2 or newer.
  27.     unload -rs $qt($script)
  28.   }
  29.   else {
  30.     echo $color(info) -at * Colour Picker loaded! Type /CP to open the Colour Picker window.
  31.     cp.createicon
  32.   }
  33. }
  34.  
  35. on *:unload: {
  36.   cp.close
  37.   unset %cp.*
  38.   .remove $qt($scriptdirColour Picker RGB.bmp)
  39.   .remove $qt($scriptdirColour Picker mIRC.bmp)
  40. }
  41.  
  42. menu menubar {
  43.   Colour Picker
  44.   .$+(Colour Picker,$chr(9),/cp):cp
  45.   .-
  46.   .Uninstall:if ($input(Do you really want to uninstall Colour Picker?,yqu,Colour Picker)) unload -rs $qt($script)
  47. }
  48.  
  49. alias cp {
  50.   if ($window(@Colour)) window -a @Colour
  51.   else {
  52.     set -l %icon $qt($scriptdirCube.ico)
  53.     window -pdfk0w0B +ftn @Colour -1 -1 800 600 %icon
  54.     titlebar @Colour Picker - /CP
  55.     drawsize @Colour 800 600
  56.  
  57.     :tryagain
  58.     if (!%cp.c.bitmap) %cp.c.bitmap = $qt($scriptdirColour Picker RGB.bmp)
  59.     if (!$isfile(%cp.c.bitmap)) {
  60.       if ($nopath(%cp.c.bitmap) == Colour Picker RGB.bmp) cp.generatergb
  61.       elseif ($nopath(%cp.c.bitmap) == Colour Picker mIRC.bmp) cp.generatemirc
  62.       else {
  63.         %cp.c.bitmap =
  64.         goto tryagain
  65.       }
  66.     }
  67.     else drawpic -c @Colour 0 0 %cp.c.bitmap
  68.  
  69.     hfree -w cp.*
  70.     hmake cp.colours
  71.     hmake cp.database
  72.     set -l %x 0
  73.     while (%x <= 98) {
  74.       tokenize 1 $rgb($color(%x))
  75.       hadd cp.colours $1 $hget(cp.colours,$1) %x
  76.       inc %x
  77.     }
  78.  
  79.     window -phfk0 @cp.cache -1 -1 583 128 %icon
  80.     drawsize @cp.cache 583 128
  81.  
  82.     drawrect -nrf @cp.cache $rgb(face)    1 0 0   200 128
  83.     drawrect -nr  @cp.cache $rgb(frame)   1 0 0   200 128
  84.     drawtext -nro @cp.cache $rgb(text) Tahoma -8 $calc(51-$width(Current colour,Tahoma,-8,1)/2) 2 Current colour
  85.     drawline -nr  @cp.cache $rgb(shadow)  1 5 48  5   17 97 17
  86.     drawline -nr  @cp.cache $rgb(3dlight) 1 5 48  97  48 97 16
  87.     drawrect -nr  @cp.cache $rgb(frame)   1 5 53  93  16
  88.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 6 54  91  14
  89.     drawrect -nr  @cp.cache $rgb(frame)   1 5 71  93  16
  90.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 6 72  91  14
  91.     drawrect -nr  @cp.cache $rgb(frame)   1 5 89  93  16
  92.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 6 90  91  14
  93.     drawrect -nr  @cp.cache $rgb(frame)   1 5 107 93  16
  94.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 6 108 91  14
  95.  
  96.     drawtext -nro @cp.cache $rgb(text) Tahoma -8 $calc(148-$width(Selected colour,Tahoma,-8,1)/2) 2 Selected colour
  97.     drawline -nr  @cp.cache $rgb(shadow)  1 102 48 102 17 194 17
  98.     drawline -nr  @cp.cache $rgb(3dlight) 1 102 48 194 48 194 16
  99.     drawrect -nr  @cp.cache $rgb(frame)   1 102 53  93  16
  100.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 103 54  91  14
  101.     drawrect -nr  @cp.cache $rgb(frame)   1 102 71  93  16
  102.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 103 72  91  14
  103.     drawrect -nr  @cp.cache $rgb(frame)   1 102 89  93  16
  104.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 103 90  91  14
  105.     drawrect -nr  @cp.cache $rgb(frame)   1 102 107 93  16
  106.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 103 108 91  14
  107.  
  108.     window -phfk0 @cp.preview -1 -1 200 128 %icon
  109.     drawsize @cp.preview 200 128
  110.  
  111.     %cp.c.xoffset = +10
  112.     %cp.c.yoffset =
  113.     %cp.c.lastposition = 0 0
  114.  
  115.     if (%cp.s.selecteddecimal !isnum 0-16777215) {
  116.       %cp.s.selectedrgb = 0,0,0
  117.       %cp.s.selectedhex = #000000
  118.       %cp.s.selecteddecimal = 0
  119.       %cp.s.selectedmirc = $cp.match(%cp.s.selecteddecimal)
  120.     }
  121.     drawcopy -n @cp.cache 0 0 200 128 @cp.preview 0 0
  122.     drawrect -nrf @cp.preview %cp.s.selecteddecimal 1 103 18 91 30
  123.     drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(148.5-$width(%cp.s.selectedrgb,Tahoma,-8)/2) 54 91 16 %cp.s.selectedrgb
  124.     drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(148.5-$width(%cp.s.selectedhex,Tahoma,-8)/2) 72 91 14 %cp.s.selectedhex
  125.     drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(148.5-$width(%cp.s.selecteddecimal,Tahoma,-8)/2) 90 91 14 %cp.s.selecteddecimal
  126.     drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(148.5-$width(%cp.s.selectedmirc,Tahoma,-8)/2) 108 91 14 %cp.s.selectedmirc
  127.  
  128.     drawrect -nrf @cp.cache $rgb(3dlight) 1 200 74 10  20
  129.     drawrect -nr  @cp.cache $rgb(frame)   1 200 74 10  20
  130.  
  131.     drawrect -nrf @cp.cache $rgb(face)    1 200 0 360 74
  132.     drawrect -nr  @cp.cache $rgb(frame)   1 200 0 360 74
  133.  
  134.     ;drawrect -nr  @cp.cache $rgb(frame)   1 240 4  150 20
  135.     drawtext -nr  @cp.cache $rgb(text) Tahoma -8 205 6 Red
  136.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 245 12 140 4
  137.     drawrect -nr  @cp.cache $rgb(shadow)  1 245 12 140 4
  138.     drawrect -nr  @cp.cache $rgb(frame)   1 395 6  40  16
  139.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 396 7  38  14
  140.  
  141.     ;drawrect -nr  @cp.cache $rgb(frame)   1 240 27  150 20
  142.     drawtext -nr  @cp.cache $rgb(text) Tahoma -8 205 29 Green
  143.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 245 35 140 4
  144.     drawrect -nr  @cp.cache $rgb(shadow)  1 245 35 140 4
  145.     drawrect -nr  @cp.cache $rgb(frame)   1 395 29 40  16
  146.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 396 30 38  14
  147.  
  148.     ;drawrect -nr  @cp.cache $rgb(frame)   1 240 50  150 20
  149.     drawtext -nr  @cp.cache $rgb(text) Tahoma -8 205 52 Blue
  150.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 245 58 140 4
  151.     drawrect -nr  @cp.cache $rgb(shadow)  1 245 58 140 4
  152.     drawrect -nr  @cp.cache $rgb(frame)   1 395 52 40  16
  153.     drawrect -nrf @cp.cache $cp.invert($rgb($rgb(text))) 1 396 53 38  14
  154.  
  155.     drawline -nr  @cp.cache $rgb(shadow)  1 480 68 480 5  504 5
  156.     drawline -nr  @cp.cache $rgb(3dlight) 1 480 68 504 68 504 4
  157.  
  158.     drawline -nr  @cp.cache $rgb(shadow)  1 510 68 510 5  554 5
  159.     drawline -nr  @cp.cache $rgb(3dlight) 1 510 68 554 68 554 4
  160.  
  161.     %cp.s.sliders = 1
  162.     %cp.s.sliderx = 10
  163.     %cp.s.slidery = 515
  164.  
  165.     ;window -pdfk0w0B +ftL @cp.sliders -1 -1 360 74 %icon
  166.     window -phfk0 @cp.sliders -1 -1 360 74 %icon
  167.     drawsize @cp.sliders 360 74
  168.  
  169.     cp.drawsliders
  170.   }
  171. }
  172.  
  173. alias -l cp.invert {
  174.   tokenize 44 $1
  175.   return $rgb($calc(255*(1-$1 /255)),$calc(255*(1-$2 /255)),$calc(255*(1-$3 /255)))
  176. }
  177.  
  178. alias -l cp.drawsliders {
  179.   drawcopy -n @cp.cache 200 0 360 74 @cp.sliders 0 0
  180.  
  181.   tokenize 44 %cp.s.selectedrgb
  182.   set -l %t $calc($1 +$2 +$3)
  183.   tokenize 32 $1-3 $round($calc(($1 /%t)*100),1) $+ % $round($calc(($2 /%t)*100),1) $+ % $round($calc(($3 /%t)*100),1) $+ %
  184.  
  185.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($1 /255))) 4
  186.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($2 /255))) 27
  187.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($3 /255))) 50
  188.  
  189.   if (%cp.c.object == 1) drawrect -nr @cp.sliders $rgb(frame) 1 40 4  150 20
  190.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($1,Tahoma,-8)/2)) 7 38 14 $1
  191.   if (%cp.c.object == 2) drawrect -nr @cp.sliders $rgb(frame) 1 40 27 150 20
  192.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($2,Tahoma,-8)/2)) 30 38 14 $2
  193.   if (%cp.c.object == 3) drawrect -nr @cp.sliders $rgb(frame) 1 40 50 150 20
  194.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($3,Tahoma,-8)/2)) 53 38 14 $3
  195.  
  196.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($4,Tahoma,-8)) 6  $4
  197.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($5,Tahoma,-8)) 29 $5
  198.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($6,Tahoma,-8)) 52 $6
  199.  
  200.   set -l %a 30
  201.   set -l %1 $1
  202.   set -l %2 $2
  203.   set -l %3 $3
  204.   set -l %b 61
  205.   set -l %4 0
  206.   set -l %5 0
  207.   set -l %6 0
  208.   tokenize 32 $calc((255-$1)/30) $calc((255-$2)/30) $calc((255-$3)/30) $calc($1 /30) $calc($2 /30) $calc($3 /30)
  209.   while (%a >= 0) {
  210.     drawline -nr @cp.cache $rgb(%1,%2,%3) 1 560 %a 583 %a
  211.     dec %a
  212.     inc %1 $1
  213.     inc %2 $2
  214.     inc %3 $3
  215.     drawline -nr @cp.cache $rgb(%4,%5,%6) 1 560 %b 583 %b
  216.     dec %b
  217.     inc %4 $4
  218.     inc %5 $5
  219.     inc %6 $6
  220.   }
  221.   drawcopy -n @cp.cache 560 0 23 62 @cp.sliders 281 6
  222.   drawline -nri @cp.sliders 0 1 281 36 303 36 303 38 281 38 281 36
  223.   %cp.c.brightness = 37
  224.  
  225.   drawrect -nrf @cp.sliders %cp.s.selecteddecimal 1 311 6 43 62
  226.  
  227.   drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  228. }
  229.  
  230. alias -l cp.updatesliders {
  231.   %cp.c.object = $1
  232.   %cp.s.selectedrgb = $puttok(%cp.s.selectedrgb,$2,$1,44)
  233.   tokenize 44 %cp.s.selectedrgb
  234.   %cp.s.selecteddecimal = $rgb($1,$2,$3)
  235.   %cp.s.selectedhex = $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2))
  236.   %cp.s.selectedmirc = $cp.match(%cp.s.selecteddecimal)
  237.   cp.drawsliders
  238.   drawdot @Colour
  239.   %cp.c.updateneeded = 1
  240. }
  241.  
  242. alias -l cp.updatebrightness {
  243.   %cp.c.brightness = $1
  244.  
  245.   drawcopy -n @cp.cache 200 0 360 74 @cp.sliders 0 0
  246.   drawcopy -n @cp.cache 560 0 23 62 @cp.sliders 281 6
  247.  
  248.   drawrect -nr @cp.sliders $rgb(frame) 1 280 5 25 64
  249.  
  250.   drawline -nri @cp.sliders 0 1 281 $calc($1 -1) 303 $calc($1 -1) 303 $calc($1 +1) 281 $calc($1 +1) 281 $calc($1 -1)
  251.  
  252.   %cp.s.selecteddecimal = $getdot(@cp.sliders,290,$1)
  253.   %cp.s.selectedrgb = $rgb(%cp.s.selecteddecimal)
  254.   tokenize 44 %cp.s.selectedrgb
  255.   %cp.s.selectedhex = $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2))
  256.   %cp.s.selectedmirc = $cp.match(%cp.s.selecteddecimal)
  257.  
  258.   set -l %t $calc($1 +$2 +$3)
  259.   tokenize 32 $1-3 $round($calc(($1 /%t)*100),1) $+ % $round($calc(($2 /%t)*100),1) $+ % $round($calc(($3 /%t)*100),1) $+ %
  260.  
  261.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($1 /255))) 4
  262.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($2 /255))) 27
  263.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($3 /255))) 50
  264.  
  265.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($1,Tahoma,-8)/2)) 7 38 14 $1
  266.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($2,Tahoma,-8)/2)) 30 38 14 $2
  267.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($3,Tahoma,-8)/2)) 53 38 14 $3
  268.  
  269.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($4,Tahoma,-8)) 6  $4
  270.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($5,Tahoma,-8)) 29 $5
  271.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($6,Tahoma,-8)) 52 $6
  272.  
  273.   drawrect -nrf @cp.sliders %cp.s.selecteddecimal 1 311 6 43 62
  274.  
  275.   drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  276.   drawdot @Colour
  277.   %cp.c.updateneeded = 1
  278. }
  279.  
  280. ;DOWN/LEFT
  281. on *:keydown:@Colour:37,40: {
  282.   if (%cp.c.object == 4) {
  283.     inc %cp.c.brightness
  284.     if (%cp.c.brightness > 67) cp.updatebrightness 67
  285.     else cp.updatebrightness %cp.c.brightness
  286.   }
  287.   elseif (%cp.c.object isnum 1-3) {
  288.     set -l %v $gettok(%cp.s.selectedrgb,%cp.c.object,44)
  289.     dec %v
  290.     if (%v < 0) %v = 0
  291.     %cp.s.selectedrgb = $puttok(%cp.s.selectedrgb,%v,%cp.c.object,44)
  292.     cp.updateslidersx
  293.   }
  294. }
  295.  
  296. alias -l cp.updateslidersx {
  297.   tokenize 44 %cp.s.selectedrgb
  298.   %cp.s.selecteddecimal = $rgb($1,$2,$3)
  299.   %cp.s.selectedhex = $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2))
  300.   %cp.s.selectedmirc = $cp.match(%cp.s.selecteddecimal)
  301.   cp.drawsliders
  302.   drawdot @Colour
  303.   %cp.c.updateneeded = 1
  304. }
  305.  
  306. ;UP/RIGHT
  307. on *:keydown:@Colour:38,39: {
  308.   if (%cp.c.object == 4) {
  309.     dec %cp.c.brightness
  310.     if (%cp.c.brightness < 6) cp.updatebrightness 6
  311.     else cp.updatebrightness %cp.c.brightness
  312.   }
  313.   elseif (%cp.c.object isnum 1-3) {
  314.     set -l %v $gettok(%cp.s.selectedrgb,%cp.c.object,44)
  315.     inc %v
  316.     if (%v > 255) %v = 255
  317.     %cp.s.selectedrgb = $puttok(%cp.s.selectedrgb,%v,%cp.c.object,44)
  318.     cp.updateslidersx
  319.   }
  320. }
  321.  
  322. ;1-9
  323. on *:keydown:@Colour:48,49,50,51,52,53,54,55,56,57: {
  324.   if (%cp.c.object isnum 1-3) cp.editrgb %cp.c.object $keychar $gettok(%cp.s.selectedrgb,%cp.c.object,44)
  325. }
  326.  
  327. alias -l cp.editrgb {
  328.   if ($len($3) >= 3) beep 1
  329.   else {
  330.     set -l %v $3 $+ $2
  331.     while ($left(%v,1) == 0) && ($len(%v) > 1) %v = $mid(%v,2-)
  332.     if (%v > 255) beep 1
  333.     elseif (%v < 0) beep 1
  334.     else {
  335.       %cp.s.selectedrgb = $puttok(%cp.s.selectedrgb,%v,$1,44)
  336.       cp.updateslidersx
  337.     }
  338.   }
  339. }
  340.  
  341. ;BACKSPACE
  342. on *:keydown:@Colour:8: {
  343.   if (%cp.c.object isnum 1-3) cp.delrgb %cp.c.object $gettok(%cp.s.selectedrgb,%cp.c.object,44)
  344. }
  345.  
  346. alias -l cp.delrgb {
  347.   if ($2 == 0) beep 1
  348.   else {
  349.     set -l %v $left($2,-1)
  350.     if (!%v) %v = 0
  351.     %cp.s.selectedrgb = $puttok(%cp.s.selectedrgb,%v,$1,44)
  352.     cp.updateslidersx
  353.   }
  354. }
  355.  
  356. ;TAB
  357. on *:keydown:@Colour:9: {
  358.   inc %cp.c.object
  359.   if (%cp.c.object > 4) %cp.c.object = 1
  360.  
  361.   drawcopy -n @cp.cache 200 0 360 74 @cp.sliders 0 0
  362.   drawcopy -n @cp.cache 560 0 23 62 @cp.sliders 281 6
  363.  
  364.   drawline -nri @cp.sliders 0 1 281 $calc(%cp.c.brightness -1) 303 $calc(%cp.c.brightness -1) 303 $calc(%cp.c.brightness +1) 281 $calc(%cp.c.brightness +1) 281 $calc(%cp.c.brightness -1)
  365.  
  366.   tokenize 44 %cp.s.selectedrgb
  367.   set -l %t $calc($1 +$2 +$3)
  368.   tokenize 32 $1-3 $round($calc(($1 /%t)*100),1) $+ % $round($calc(($2 /%t)*100),1) $+ % $round($calc(($3 /%t)*100),1) $+ %
  369.  
  370.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($1 /255))) 4
  371.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($2 /255))) 27
  372.   drawcopy -n   @cp.cache   200 74 10 20 @cp.sliders $calc(40+(140*($3 /255))) 50
  373.  
  374.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($1,Tahoma,-8)/2)) 7 38 14 $1
  375.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($2,Tahoma,-8)/2)) 30 38 14 $2
  376.   drawtext -nrc @cp.sliders $rgb(text) Tahoma -8 $calc(215-($width($3,Tahoma,-8)/2)) 53 38 14 $3
  377.  
  378.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($4,Tahoma,-8)) 6  $4
  379.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($5,Tahoma,-8)) 29 $5
  380.   drawtext -nr  @cp.sliders $rgb(text) Tahoma -8 $calc(275-$width($6,Tahoma,-8)) 52 $6
  381.  
  382.   drawrect -nrf @cp.sliders %cp.s.selecteddecimal 1 311 6 43 62
  383.  
  384.   if (%cp.c.object == 1) drawrect -nr @cp.sliders $rgb(frame) 1 40 4  150 20
  385.   elseif (%cp.c.object == 2) drawrect -nr @cp.sliders $rgb(frame) 1 40 27 150 20
  386.   elseif (%cp.c.object == 3) drawrect -nr @cp.sliders $rgb(frame) 1 40 50 150 20
  387.   elseif (%cp.c.object == 4) drawrect -nr @cp.sliders $rgb(frame) 1 280 5 25 64
  388.  
  389.   drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  390.  
  391.   drawdot @Colour
  392. }
  393.  
  394. ;CTRL+C
  395. on *:keydown:@Colour:67: {
  396.   if ($asc($keychar) == 3) && ($input(What would you like to copy?,qms,@Colour,Colour Picker,RGB: %cp.s.selectedrgb,RGB: %cp.s.selectedrgb,HEX: %cp.s.selectedhex,Decimal: %cp.s.selecteddecimal,mIRC: %cp.s.selectedmirc)) clipboard $gettok($v1,2-,32)
  397. }
  398.  
  399. ;CTRL+V
  400. on *:keydown:@Colour:86: {
  401.   if ($asc($keychar) == 22) {
  402.     tokenize 32 $cb
  403.     if (*?,?*,?* iswm $cb) cp.loadrgb $replacex($cb,$chr(44),$chr(32))
  404.     elseif ($1 isnum 0-255) && ($2 isnum 0-255) && ($3 isnum 0-255) cp.loadrgb $1-3
  405.     elseif (#?????? iswm $cb) cp.loadrgb $base($mid($cb,2,2),16,10) $base($mid($cb,4,2),16,10) $base($mid($cb,6,2),16,10)
  406.     elseif ($base($mid($cb,1,2),16,10) isnum 0-255) && ($base($mid($cb,3,2),16,10) isnum 0-255) && ($base($mid($cb,5,2),16,10) isnum 0-255) cp.loadrgb $base($mid($cb,1,2),16,10) $base($mid($cb,3,2),16,10) $v1
  407.     elseif (#??? iswm $cb) cp.loadrgb $base($str($mid($cb,2,1),2),16,10) $base($str($mid($cb,3,1),2),16,10) $base($str($mid($cb,4,1),2),16,10)
  408.     elseif ($base($str($mid($cb,1,1),2),16,10) isnum 0-255) && ($base($str($mid($cb,2,1),2),16,10) isnum 0-255) && ($base($str($mid($cb,3,1),2),16,10) isnum 0-255) cp.loadrgb $base($str($mid($cb,1,1),2),16,10) $base($str($mid($cb,2,1),2),16,10) $v1
  409.     elseif ($cb isnum 0-16777215) cp.loadrgb $rgb($cb)
  410.     else beep 1
  411.   }
  412. }
  413.  
  414. alias -l cp.loadrgb {
  415.   if ($1 isnum 0-255) && ($2 isnum 0-255) && ($3 isnum 0-255) {
  416.     %cp.s.selecteddecimal = $rgb($1,$2,$3)
  417.     %cp.s.selectedrgb = $rgb(%cp.s.selecteddecimal)
  418.     tokenize 44 %cp.s.selectedrgb
  419.     %cp.s.selectedhex = $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2))
  420.     %cp.s.selectedmirc = $cp.match(%cp.s.selecteddecimal)
  421.     cp.drawsliders
  422.     if (%cp.c.visible) cp.drawselected %cp.s.selecteddecimal
  423.     else %cp.s.history = $gettok($instok($remtok(%cp.s.history,%cp.selectedrgb,0,32),%cp.s.selectedrgb,1,32),1-10,32)
  424.     drawdot @Colour
  425.   }
  426.   else beep 1
  427. }
  428.  
  429. menu @Colour {
  430.   uclick:unset %cp.c.x %cp.c.y %cp.c.move
  431.   leave: {
  432.     unset %cp.c.x %cp.c.y %cp.c.move
  433.     drawpic -nc @Colour %cp.c.lastposition %cp.c.lastposition 200 128 %cp.c.bitmap
  434.     if (%cp.s.sliders) drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  435.     drawdot @Colour
  436.   }
  437.   mouse: {
  438.     set -l %x $mouse.x
  439.     set -l %y $mouse.y
  440.     set -l %relativex %x - %cp.s.sliderx
  441.     set -l %relativey %y - %cp.s.slidery
  442.     if (%cp.c.move == brightness) {
  443.       if (%relativey < 6) %relativey = 6
  444.       elseif (%relativey > 67) %relativey = 67
  445.       cp.updatebrightness %relativey
  446.     }
  447.     elseif (%cp.c.move) {
  448.       if (%relativex <= 45) set -l %v 0
  449.       elseif (%relativex >= 185) set -l %v 255
  450.       else set -l %v $round($calc(255*((%relativex -45)/140)),0)
  451.       cp.updatesliders %cp.c.move %v
  452.     }
  453.     elseif (%cp.c.x isnum) {
  454.       set -l %nx $calc(%x -(%cp.c.x -%cp.s.sliderx))
  455.       set -l %ny $calc(%y -(%cp.c.y -%cp.s.slidery))
  456.       if (%nx < 0) %nx = 0
  457.       elseif ($calc(%nx +360) > 800) %nx = 800 - 360
  458.       if (%ny < 0) %ny = 0
  459.       elseif ($calc(%ny +74) > 600) %ny = 600 - 74
  460.       drawpic -nc @Colour %cp.s.sliderx %cp.s.slidery %cp.s.sliderx %cp.s.slidery 360 74 %cp.c.bitmap
  461.       %cp.s.sliderx = %nx
  462.       %cp.s.slidery = %ny
  463.       %cp.c.x = %x
  464.       %cp.c.y = %y
  465.       drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  466.       drawdot @Colour
  467.     }
  468.     elseif (%cp.s.sliders) && ($inrect(%x,%y,%cp.s.sliderx,%cp.s.slidery,360,74)) {
  469.       if (%cp.c.visible) {
  470.         drawpic -nc @Colour %cp.c.lastposition %cp.c.lastposition 200 128 %cp.c.bitmap
  471.         drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  472.         drawdot @Colour
  473.         %cp.c.visible =
  474.       }
  475.     }
  476.     else {
  477.       if (%cp.c.updateneeded) cp.updateselected
  478.       %cp.c.visible = 1
  479.       if (%x > 590) %cp.c.xoffset = -210
  480.       elseif (%x < 210) %cp.c.xoffset = +10
  481.       if (%y > 472) %cp.c.yoffset = -128
  482.       elseif (%y < 128) %cp.c.yoffset =
  483.       drawpic -nc @Colour %cp.c.lastposition %cp.c.lastposition 200 128 %cp.c.bitmap
  484.       if (%cp.s.sliders) drawcopy -n @cp.sliders 0 0 360 74 @Colour %cp.s.sliderx %cp.s.slidery
  485.       %cp.c.lastposition = $calc(%x %cp.c.xoffset) $calc(%y %cp.c.yoffset)
  486.       if (*\Colour Picker mIRC.bmp" iswm %cp.c.bitmap) {
  487.         if (%y <= 138) cp.drawcurrent $getdot(@Colour,$calc($floor($calc(%x /100))*100+50),%y)
  488.         else cp.drawcurrent $getdot(@Colour,$calc($floor($calc(%x /67))*67+50),%y)
  489.       }
  490.       else cp.drawcurrent $getdot(@Colour,%x,%y)
  491.     }
  492.   }
  493.   sclick: {
  494.     set -l %x $mouse.x
  495.     set -l %y $mouse.y
  496.     if (%cp.s.sliders) && ($inrect(%x,%y,%cp.s.sliderx,%cp.s.slidery,360,74)) {
  497.       tokenize 44 %cp.s.selectedrgb
  498.  
  499.       set -l %relativex %x - %cp.s.sliderx
  500.       set -l %relativey %y - %cp.s.slidery
  501.  
  502.       if (%relativex <= 45) set -l %v 0
  503.       elseif (%relativex >= 185) set -l %v 255
  504.       else set -l %v $round($calc(255*((%relativex -45)/140)),0)
  505.  
  506.       if ($inrect(%relativex,%relativey,195,6,40,16)) {
  507.         %cp.c.object = 1
  508.         cp.drawsliders
  509.         drawdot @Colour
  510.       }
  511.       elseif ($inrect(%relativex,%relativey,$calc(40+(140*($1 /255))),4,10,20)) {
  512.         %cp.c.move = 1
  513.         %cp.c.object = 1
  514.       }
  515.       elseif ($inrect(%relativex,%relativey,40,4,150,20)) cp.updatesliders 1 %v
  516.       elseif ($inrect(%relativex,%relativey,195,29,40,16)) {
  517.         %cp.c.object = 2
  518.         cp.drawsliders
  519.         drawdot @Colour
  520.       }
  521.       elseif ($inrect(%relativex,%relativey,$calc(40+(140*($2 /255))),27,10,20)) {
  522.         %cp.c.move = 2
  523.         %cp.c.object = 2
  524.       }
  525.       elseif ($inrect(%relativex,%relativey,40,27,150,20)) cp.updatesliders 2 %v
  526.       elseif ($inrect(%relativex,%relativey,195,52,40,16)) {
  527.         %cp.c.object = 3
  528.         cp.drawsliders
  529.         drawdot @Colour
  530.       }
  531.       elseif ($inrect(%relativex,%relativey,$calc(40+(140*($3 /255))),50,10,20)) {
  532.         %cp.c.move = 3
  533.         %cp.c.object = 3
  534.       }
  535.       elseif ($inrect(%relativex,%relativey,40,50,150,20)) cp.updatesliders 3 %v
  536.       elseif ($inrect(%relativex,%relativey,281,6,23,62)) {
  537.         %cp.c.move = brightness
  538.         %cp.c.object = 4
  539.         cp.updatebrightness %relativey
  540.       }
  541.       else {
  542.         %cp.c.x = %x
  543.         %cp.c.y = %y
  544.       }
  545.     }
  546.     else {
  547.       if (%cp.c.updateneeded) cp.updateselected
  548.       if (%x > 590) %cp.c.xoffset = -210
  549.       elseif (%x < 210) %cp.c.xoffset = +10
  550.       if (%y > 472) %cp.c.yoffset = -128
  551.       elseif (%y < 128) %cp.c.yoffset =
  552.       drawpic -nc @Colour %cp.c.lastposition %cp.c.lastposition 200 128 %cp.c.bitmap
  553.       %cp.c.lastposition = $calc(%x %cp.c.xoffset) $calc(%y %cp.c.yoffset)
  554.       if (*\Colour Picker mIRC.bmp" iswm %cp.c.bitmap) {
  555.         if (%y <= 138) cp.drawselected $getdot(@Colour,$calc($floor($calc(%x /100))*100+50),%y)
  556.         else cp.drawselected $getdot(@Colour,$calc($floor($calc(%x /67))*67+50),%y)
  557.       }
  558.       else cp.drawselected $getdot(@Colour,%x,%y)
  559.     }
  560.   }
  561.   $+(Red Green Blue,$chr(9),%cp.s.selectedrgb) :clipboard %cp.s.selectedrgb
  562.   $+(Hexadecimal,$chr(9),%cp.s.selectedhex) :clipboard %cp.s.selectedhex
  563.   $+(Decimal,$chr(9),%cp.s.selecteddecimal) :clipboard %cp.s.selecteddecimal
  564.   $+(mIRC,$chr(9),%cp.s.selectedmirc) :clipboard %cp.s.selectedmirc
  565.   -
  566.   Bitmap...
  567.   .$iif(*\Colour Picker RGB.bmp" iswm %cp.c.bitmap,$style(1)) $+(Full RGB,$chr(9),CTRL+B):cp.rgbbitmap
  568.   .$iif(*\Colour Picker mIRC.bmp" iswm %cp.c.bitmap,$style(1)) $+(mIRC colours,$chr(9),CTRL+M):cp.mircbitmap
  569.   .-
  570.   .$iif((*\Colour Picker mIRC.bmp" iswm %cp.c.bitmap) && (*\Colour Picker RGB.bmp" iswm %cp.c.bitmap),$style(1)) Custom image...: {
  571.     if ($sfile($iif($isdir($nofile(%cp.c.bitmap)),$nofile(%cp.c.bitmap),$scriptdir) *.jpg;*.jpeg;*.png;*.bmp;*.gif,Choose an image,Open)) {
  572.       %cp.c.bitmap = $qt($v1)
  573.       drawpic -c
  574.       drawrect -nrf @Colour 0 1 0 0 800 600
  575.       drawpic -nc @Colour 0 0 %cp.c.bitmap
  576.       drawdot @Colour
  577.     }
  578.     if ($error) {
  579.       reseterror
  580.       noop $input(Invalid image file.,ohu,Colour Picker)
  581.       %cp.c.bitmap = $qt($scriptdirColour Picker RGB.bmp)
  582.       if (!$isfile(%cp.c.bitmap)) cp.generatergb
  583.       else drawpic -c @Colour 0 0 %cp.c.bitmap
  584.     }
  585.   }
  586.   -
  587.   $+(Invert selected colour,$chr(9),CTRL+I):cp.drawselected $cp.invert(%cp.s.selectedrgb)
  588.   $+(Random colour,$chr(9),CTRL+R): {
  589.     if ($nopath(%cp.c.bitmap) == Colour Picker mIRC.bmp) cp.drawselected $color($r(0,98))
  590.     else cp.drawselected $rgb($r(0,255),$r(0,255),$r(0,255))
  591.   }
  592.   -
  593.   History...
  594.   .$submenu($cp.history($1))
  595.   -
  596.   Close:cp.close
  597. }
  598.  
  599. ;CTRL+M
  600. on *:keydown:@Colour:77:if ($asc($keychar) == 13) cp.mircbitmap
  601.  
  602. alias -l cp.mircbitmap  {
  603.   if (*\Colour Picker mIRC.bmp" iswm %cp.c.bitmap) && ($input(mIRC bitmap already selected $+ $chr(44) do you want to regenerate the bitmap?,yqu,Colour Picker)) cp.generatemirc
  604.   else {
  605.     drawpic -c
  606.     %cp.c.bitmap = $qt($scriptdirColour Picker mIRC.bmp)
  607.     if (!$isfile(%cp.c.bitmap)) cp.generatemirc
  608.     else drawpic -c @Colour 0 0 %cp.c.bitmap
  609.   }
  610. }
  611.  
  612. ;CTRL+B
  613. on *:keydown:@Colour:66:if ($asc($keychar) == 2) cp.rgbbitmap
  614.  
  615. alias -l cp.rgbbitmap {
  616.   if (*\Colour Picker RGB.bmp" iswm %cp.c.bitmap) && ($input(Full RGB bitmap already selected $+ $chr(44) do you want to regenerate the bitmap?,yqu,Colour Picker)) cp.generatergb
  617.   else {
  618.     drawpic -c
  619.     %cp.c.bitmap = $qt($scriptdirColour Picker RGB.bmp)
  620.     if (!$isfile(%cp.c.bitmap)) cp.generatergb
  621.     else drawpic -c @Colour 0 0 %cp.c.bitmap
  622.   }
  623. }
  624.  
  625. ;CTRL+I
  626. on *:keydown:@Colour:73: {
  627.   if ($asc($keychar) == 9) {
  628.     tokenize 44 %cp.s.selectedrgb
  629.     cp.drawselected $rgb($calc(255*(1-$1 /255)),$calc(255*(1-$2 /255)),$calc(255*(1-$3 /255)))
  630.   }
  631. }
  632.  
  633. ;CTRL+R
  634. on *:keydown:@Colour:82: {
  635.   if ($asc($keychar) == 18) {
  636.     if ($nopath(%cp.c.bitmap) == Colour Picker mIRC.bmp) cp.drawselected $color($r(0,98))
  637.     else cp.drawselected $rgb($r(0,255),$r(0,255),$r(0,255))
  638.   }
  639. }
  640.  
  641. alias -l cp.history {
  642.   if ($1 == begin) return -
  643.   elseif ($gettok(%cp.s.history,$1,32)) return $v1 :cp.loadrgb $replacex($v1,$chr(44),$chr(32))
  644.   else return -
  645. }
  646.  
  647. alias -l cp.drawcurrent {
  648.   set -l %v $1
  649.   tokenize 44 $rgb(%v)
  650.   drawcopy -n @cp.cache 0 0 100 128 @cp.preview 0 0
  651.   drawrect -nrf @cp.preview %v 1 6 18 91 30
  652.   drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(51.5-$width($1-3,Tahoma,-8)/2) 54 91 16 $rgb(%v)
  653.   set -l %h $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2))
  654.   drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(51.5-$width(%h,Tahoma,-8)/2) 72 91 14 %h
  655.   drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(51.5-$width(%v,Tahoma,-8)/2) 90 91 14 %v
  656.   set -l %m $cp.match(%v)
  657.   drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(51.5-$width(%m,Tahoma,-8)/2) 108 91 14 %m
  658.   drawcopy -n @cp.preview 0 0 200 128 @Colour %cp.c.lastposition
  659.   drawdot @Colour
  660. }
  661.  
  662. alias -l cp.drawselected {
  663.   %cp.s.selecteddecimal = $1
  664.   %cp.s.selectedrgb = $rgb($1)
  665.   tokenize 44 %cp.s.selectedrgb
  666.   drawcopy -n @cp.cache 0 0 200 128 @cp.preview 0 0
  667.   drawrect -nrf @cp.preview %cp.s.selecteddecimal 1 6 18 91 30 103 18 91 30
  668.   cp.drawtext 54 $width(%cp.s.selectedrgb,Tahoma,-8) %cp.s.selectedrgb
  669.   %cp.s.selectedhex = $+($chr(35),$base($1,10,16,2),$base($2,10,16,2),$base($3,10,16,2))
  670.   cp.drawtext 72 $width(%cp.s.selectedhex,Tahoma,-8) %cp.s.selectedhex
  671.   cp.drawtext 90 $width(%cp.s.selecteddecimal,Tahoma,-8) %cp.s.selecteddecimal
  672.   %cp.s.selectedmirc = $cp.match(%cp.s.selecteddecimal)
  673.   cp.drawtext 108 $width(%cp.s.selectedmirc,Tahoma,-8) %cp.s.selectedmirc
  674.   cp.drawsliders
  675.   %cp.s.history = $gettok($instok($remtok(%cp.s.history,%cp.selectedrgb,0,32),%cp.s.selectedrgb,1,32),1-10,32)
  676.   drawcopy -n @cp.preview 0 0 200 128 @Colour %cp.c.lastposition
  677.   drawdot @Colour
  678. }
  679.  
  680. alias -l cp.updateselected {
  681.   %cp.c.updateneeded =
  682.   drawcopy -n @cp.cache 0 0 200 128 @cp.preview 0 0
  683.   drawrect -nrf @cp.preview %cp.s.selecteddecimal 1 6 18 91 30 103 18 91 30
  684.   cp.drawtext 54 $width(%cp.s.selectedrgb,Tahoma,-8) %cp.s.selectedrgb
  685.   cp.drawtext 72 $width(%cp.s.selectedhex,Tahoma,-8) %cp.s.selectedhex
  686.   cp.drawtext 90 $width(%cp.s.selecteddecimal,Tahoma,-8) %cp.s.selecteddecimal
  687.   cp.drawtext 108 $width(%cp.s.selectedmirc,Tahoma,-8) %cp.s.selectedmirc
  688.   %cp.s.history = $gettok($instok($remtok(%cp.s.history,%cp.selectedrgb,0,32),%cp.s.selectedrgb,1,32),1-10,32)
  689. }
  690.  
  691. alias -l cp.drawtext {
  692.   drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(51.5-$2 /2) $1 91 16 $3-
  693.   drawtext -nrc @cp.preview $rgb(text) Tahoma -8 $calc(148.5-$2 /2) $1 91 16 $3-
  694. }
  695.  
  696. on *:close:@Colour:cp.close
  697.  
  698. on *:exit:if ($window(@Colour)) cp.close
  699.  
  700. alias -l cp.close {
  701.   window -c @Colour
  702.   drawpic -c
  703.   while ($window(@cp.*,1)) window -c $v1
  704.   unset %cp.c.*
  705.   hfree -w cp.*
  706. }
  707.  
  708. alias -l cp.match {
  709.   if ($hget(cp.database,$1) != $null) return $v1
  710.   else return $cp.find($1)
  711. }
  712.  
  713. alias -l cp.find {
  714.   set -l %a $1
  715.   set -l %b a
  716.   set -l %n 1
  717.   tokenize 44 $rgb($1)
  718.   set -l %x 1
  719.   set -l %1 $1
  720.   set -l %2 $2
  721.   set -l %3 $3
  722.   while ($hget(cp.colours,%x).item) {
  723.     tokenize 44 $v1
  724.     tokenize 1 $sqrt($calc((($1 -%1)*0.3)^2+(($2 -%2)*0.59)^2+(($3 -%3)*0.11)^2))
  725.     if ($1 < %b) var %b = $v1,%n $hget(cp.colours,%x).data
  726.     elseif ($1 == %b) %n = %n $hget(cp.colours,%x).data
  727.     inc %x
  728.   }
  729.   hadd cp.database %a $replacex(%n,$chr(32),$chr(44) $+ $chr(32))
  730.   return $hget(cp.database,%a)
  731. }
  732.  
  733. alias -l cp.generatergb {
  734.   drawpic -c
  735.   drawrect -nrf @Colour $rgb(face) 1 0 0 800 600
  736.   drawtext -nro @Colour $rgb(shadow) Tahoma -20 2 2 Please wait, generating RGB bitmap...
  737.   drawtext -nro @Colour $rgb(text) Tahoma -20 0 0 Please wait, generating RGB bitmap...
  738.   drawdot @Colour
  739.   set -l %xsize 800 / 6
  740.   set -l %ysize 600 / 2
  741.   set -l %xstep 255 / %xsize
  742.   set -l %1ststep 255 / %ysize
  743.   set -l %2nd 0
  744.   set -l %3rdstep 255 / %ysize
  745.   set -l %1 0
  746.   set -l %2 2 * %xsize
  747.   set -l %3 2 * %xsize
  748.   set -l %4 4 * %xsize
  749.   set -l %5 4 * %xsize
  750.   set -l %6 6 * %xsize
  751.   while (%1 <= %xsize) {
  752.     set -l %1st 255
  753.     set -l %2ndtemp %2nd
  754.     set -l %2ndstep $calc((255-%2nd)/%ysize)
  755.     set -l %2ndtempdark %2nd
  756.     set -l %2ndstepdark %2nd / %ysize
  757.     set -l %3rd 0
  758.     set -l %ylight %ysize
  759.     set -l %ydark %ysize
  760.     while (%ylight >= 0) {
  761.       drawdot -nr @Colour $rgb(255,%2ndtemp,%3rd) 1 %1 %ylight
  762.       drawdot -nr @Colour $rgb(%2ndtemp,255,%3rd) 1 %2 %ylight
  763.       drawdot -nr @Colour $rgb(%3rd,255,%2ndtemp) 1 %3 %ylight
  764.       drawdot -nr @Colour $rgb(%3rd,%2ndtemp,255) 1 %4 %ylight
  765.       drawdot -nr @Colour $rgb(%2ndtemp,%3rd,255) 1 %5 %ylight
  766.       drawdot -nr @Colour $rgb(255,%3rd,%2ndtemp) 1 %6 %ylight
  767.       drawdot -nr @Colour $rgb(%1st,%2ndtempdark,0) 1 %1 %ydark
  768.       drawdot -nr @Colour $rgb(%2ndtempdark,%1st,0) 1 %2 %ydark
  769.       drawdot -nr @Colour $rgb(0,%1st,%2ndtempdark) 1 %3 %ydark
  770.       drawdot -nr @Colour $rgb(0,%2ndtempdark,%1st) 1 %4 %ydark
  771.       drawdot -nr @Colour $rgb(%2ndtempdark,0,%1st) 1 %5 %ydark
  772.       drawdot -nr @Colour $rgb(%1st,0,%2ndtempdark) 1 %6 %ydark
  773.       dec %1st %1ststep
  774.       dec %2ndtempdark %2ndstepdark
  775.       inc %2ndtemp %2ndstep
  776.       inc %3rd %3rdstep
  777.       dec %ylight
  778.       inc %ydark
  779.     }
  780.     inc %2nd %xstep
  781.     inc %1
  782.     dec %2
  783.     inc %3
  784.     dec %4
  785.     inc %5
  786.     dec %6
  787.     drawdot @Colour
  788.   }
  789.   drawsave -b32 @Colour %cp.c.bitmap
  790. }
  791.  
  792. alias -l cp.generatemirc {
  793.   drawpic -c
  794.   set -l %y 0
  795.   set -l %m 0
  796.   while (%m <= 15) {
  797.     set -l %x 0
  798.     while (%x <= 790) {
  799.       drawrect -nrf @Colour $color(%m) 1 %x %y 100 69
  800.       tokenize 44 $rgb($color(%m))
  801.       drawtext -nro @Colour $iif($calc(0.2126*$1 +0.7152*$2 +0.0722*$3) >= 125,0,16777215) Tahoma -20 %x %y $base(%m,10,10,2)
  802.       inc %x 100
  803.       inc %m
  804.     }
  805.     inc %y 69
  806.   }
  807.   while (%m <= 98) {
  808.     %x = 0
  809.     while (%x <= 790) {
  810.       drawrect -nrf @Colour $color(%m) 1 %x %y 67 66
  811.       tokenize 44 $rgb($color(%m))
  812.       drawtext -nro @Colour $iif($calc(0.2126*$1 +0.7152*$2 +0.0722*$3) >= 125,0,16777215) Tahoma -14 %x %y %m
  813.       inc %x 66.666667
  814.       inc %m
  815.     }
  816.     inc %y 66
  817.   }
  818.   drawrect -nrf @Colour 0 1 733 534 67 66
  819.   drawdot @Colour
  820.   drawsave -b32 @Colour %cp.c.bitmap
  821. }
  822.  
Comments (2)
Aug 2nd, 2020 - By: Koragg
It appears that the textbox backgrounds when using this in AdiIRC (beta 3.9 Build (2020/07/24 UTC) are colored (I removed the version check so that it can function properly): Screenshot to showcase better what is meant: https://imgur.com/a/aRe5dLQ <--- it might be blue as that was the first image I chose. Can the script be made to have textboxes with white background like in mIRC or is this a bug on AdiIRC's end?
Aug 3rd, 2020 - By: Dazuz
Technically it's a mistake on my part. The script uses system colours given by $rgb (https://pastebin.com/ZcbYAtyd), and it uses hilight as the background colour. I'll change it so that it'll use the inverted colour of text instead, in the next version.

For now, an instant fix would be to replace all occurrences of "$rgb(hilight)" with "16777215".