raw *:*:{ 
  if (%ub.c) {
    if ($istok(315 367 368,$numeric,32)) { haltdef }
    if ($numeric == 354) && ($2 == 69) { 
      set %ub.t $+($5,!,$remove($3,~),@,$4)
      unban.proc %ub.c %ub.t
      haltdef 
    } 
  }
}
 
alias unban {
  if ($active ischan) && (!$2) { 
    set %ub.c $active
    $iif(*!*@* iswm $1,unban.proc $active $1,$iif($1 == *,unban.proc $active *!*@*,who $1 $+(%,tnuh,$chr(44),69)))
  }
  else { 
    set %ub.c $1
    $iif(*!*@* iswm $2,unban.proc $1 $2,$iif($2 == *,unban.proc $2 *!*@*,who $2 $+(%,tnuh,$chr(44),69)))
  }
}
 
alias unban.proc {
  if (!$chan($1).ibl) .mode $1 +b
  elseif (@ isin $2) {
    var %u = 1, %x
    while ($ibl($1,0) >= %u) {
      var %mask = $ibl($1,%u)
      if ((%mask iswm $2) || ($2 iswm %mask)) {
        if ($calc($len(%x) + $len(%mask) + 2) >= $maxlenl) {
          massmode $1 -b %x
          var %x
        }
        var %x %x %mask
      }
      inc %u
    }
    if (%x) massmode $1 -b %x
  }
  .timer 1 3 unset %ub.*
}
 
alias massmode {
  while ($3) {
    mode $1 $left($2,1) $+ $str($right($2,1),$modespl) $gettok($3-,1- $+ $modespl $+ ,32)
    tokenize 32 $1-2 $gettok($3-, $+ $calc($modespl + 1) $+ -,32)
  }
}